Suppose I have a project:

app.tcl
liba.tcl
libb.tcl

and in app.tcl I use functions from liba.tcl and libb.tcl (in namespaces liba:: and libb:: respectively).

Is there a standard recommended way to import these files?

At the moment I do this (in app.tcl):

set name [info script]
if {[file type $name] == "link"} {
set name [file readlink $name]
} set ::APP_PATH [file normalize [file dirname $name]]

foreach filename {
liba.tcl
liba.tcl
} {
source -encoding utf-8 $::APP_PATH/$filename
}

But this seems a bit cumbersome.

* Mark <m.n.summerfield@googlemail.com>
| Suppose I have a project:
>
| app.tcl
| liba.tcl
| libb.tcl
>
| and in app.tcl I use functions from liba.tcl and libb.tcl (in
| namespaces liba:: and libb:: respectively).
>
| Is there a standard recommended way to import these files?

I think I would make liba and libb packages:

- liba.tcl
package provide liba 1.0

- libb.tcl
package provide libb 1.0

- new file: pkgIndex.tcl
package ifneeded liba 1.0 [list source -encoding utf-8 [file join $dir liba.tcl]]
package ifneeded libb 1.0 [list source -encoding utf-8 [file join $dir libb.tcl]]

- app.tcl
# optional (if not installed in auto_path)
lappend auto_path [file dirname [info script]]
# load liba and libb
package require liba
package require libb

If 'liba' and 'libb' are not only short versions for demo purposes,
maybe it would be a good idea to name the packages with some prefix
(app_liba etc), since plain 'liba' and 'libb' are rather generic...

HTH
R'

On Thursday, June 1, 2023 at 9:53:03 AM UTC+1, Ralf Fassel wrote:
> * Mark <m.n.sum...@googlemail.com>
> | Suppose I have a project:
> >
> | app.tcl
> | liba.tcl
> | libb.tcl
> >
> | and in app.tcl I use functions from liba.tcl and libb.tcl (in
> | namespaces liba:: and libb:: respectively).
> >
> | Is there a standard recommended way to import these files?
> I think I would make liba and libb packages:
>
> - liba.tcl
> package provide liba 1.0
>
> - libb.tcl
> package provide libb 1.0
>
> - new file: pkgIndex.tcl
> package ifneeded liba 1.0 [list source -encoding utf-8 [file join $dir liba.tcl]]
> package ifneeded libb 1.0 [list source -encoding utf-8 [file join $dir libb.tcl]]
>
> - app.tcl
> # optional (if not installed in auto_path)
> lappend auto_path [file dirname [info script]]
> # load liba and libb
> package require liba
> package require libb
>
> If 'liba' and 'libb' are not only short versions for demo purposes,
> maybe it would be a good idea to name the packages with some prefix
> (app_liba etc), since plain 'liba' and 'libb' are rather generic...
>
> HTH
> R'

Thanks. Although it actually seems more involved that what I've been doing.
Also, in pkgIndex.tcl where does $dir's value come from?

Splitting an application into multiple files must surely be a common requirement (and common practice). So I'm assuming that how to do this is documented. But where?

Anyway, here's the structure I'm using and which seems to work based on your advice.

# file: pkgIndex.tcl
set dir [file dirname [info script]]
package ifneeded app 1.0 [list source -encoding utf-8 [file join $dir app.tcl]]
package ifneeded util 1.0 [list source -encoding utf-8 [file join $dir util.tcl]]

# file: myapp.tcl # this is the file that's to be invoked, e.g., ./myapp.tcl
lappend auto_path [file dirname [info script]]
package require app
app::main

# file: app.tcl
package provide app 1.0
package require util
namespace eval app {}

proc app::main {} {
puts "app.tcl main [util::commas 1234567890]"
}

# file: util.tcl
package provide util 1.0
namespace eval util {}

proc util::commas {x} {
regsub -all \\d(?=(\\d{3})+([regexp -inline {\.\d*$} $x]$)) $x {\0,}
}

Mark <m.n.summerfield@googlemail.com> wrote:
> Anyway, here's the structure I'm using and which seems to work based
> on your advice.
>

If you are willing to restrict your filenames to a particular pattern,
the module system is even easier to use than creating 'packages'.

man tm

for the manpage on the module system.

You'd name the files

liba-1.0.0.tm
libb-1.0.0.tm

And include a "package provide" with the same version number inside.

And in your app.tcl you'd tell tm where to search:

tcl::tm::path add [file dirname [info script]]

And then you can just do:

package require liba
package require libb

in app.tcl to pull both in.

On 01/06/2023 15:07, Rich wrote:
> And include a "package provide" with the same version number inside.

That would be redundant, because the version number is already specified
in the file name and Tcl will pick it up from there. So there is no need
to include a "package provide" command in a module code.

Schelte.

Schelte <nospam@wanadoo.nl> wrote:
> On 01/06/2023 15:07, Rich wrote:
>> And include a "package provide" with the same version number inside.
>
> That would be redundant, because the version number is already
> specified in the file name and Tcl will pick it up from there. So
> there is no need to include a "package provide" command in a module
> code.

Hmm, learn something new every day.

I've been adding 'package provide #' commands that I didn't need to
add. Now I know to stop doing that for modules.

* Mark <m.n.summerfield@googlemail.com>
| On Thursday, June 1, 2023 at 9:53:03 AM UTC+1, Ralf Fassel wrote:
| > * Mark <m.n.sum...@googlemail.com>
| > - new file: pkgIndex.tcl
| > package ifneeded liba 1.0 [list source -encoding utf-8 [file join $dir liba.tcl]]
| > package ifneeded libb 1.0 [list source -encoding utf-8 [file join $dir libb.tcl]]
--<snip-snip>--
| Also, in pkgIndex.tcl where does $dir's value come from?

$dir is automatically provided by the mechanism which loads the
pkgIndex.tcl. If you look into other pkgIndexes (eg. from tcllib),
you'll see that they don't set 'dir' either.
You should omit that line from your pkgIndex.tcl.

HTH
R'