Hello developers,
I know you don't have much free time.
So I wanted to find an anti-software piracy solution. I've been thinking about creating a server/client with a socket, and hosting it in the cloud, to run in the cloud, and the client checking if it is enabled to continue running my system.

I really don't know how to do this above.

So thanks a lot for any help,

Reynaldo Henrique

Il 13/02/2023 16:16, reina...@gmail.com ha scritto:
> Hello developers,
> I know you don't have much free time.
> So I wanted to find an anti-software piracy solution. I've been thinking about creating a server/client with a socket, and hosting it in the cloud, to run in the cloud, and the client checking if it is enabled to continue running my system.
>
> I really don't know how to do this above.
>
> So thanks a lot for any help,
>
> Reynaldo Henrique

I don't know how to run a xHarbour program "in the cloud" but with a
standard hosting you can do a lot.

You could run a CGI program on a provider's server. A program that will
be executed by the Web server at request. Since providers offer this
possibility only on Linux hosts, the CGI must be compiled under Linux.

Or try a javascript solution: you can have a page on your website, with
a name difficult to guess, containing a list of valid licences and a
Javascript program. When the page is invoked, some parameters are passed
along with the URL
(www.mysite.com/Aasw54Xzvp0.html?param=1&opt=abcdef...). The script in
the page reads the parameters and emits an answer. Every time you create
a new licence, you must update the page of course. (Untested).

I suppose that other solutions are possible with PHP and SQL.

The desktop app should create a socket, emit the request to the server
and wait for an answer, then process the answer.

HTH
Dan

El lunes, 13 de febrero de 2023 a la(s) 12:16:34 UTC-3, reina... @ gmail.com escribió:
> Hello developers,
> I know you don't have much free time.
> So I wanted to find an anti-software piracy solution. I've been thinking about creating a server/client with a socket, and hosting it in the cloud, to run in the cloud, and the client checking if it is enabled to continue running my system.
>
> I really don't know how to do this above.
>
> So thanks a lot for any help,
>
> Reynaldo Henrique

Hi Reynaldo

I have developed an applet for taking snapshots (screenshots) from users periodically, and the pictures are sent to a "server" hosted wherever you wish, as it depends on internet service (it could be a server in the LAN or in any other external host).
It is based on the code below, obviously modified in many different ways.

This code was published in the docs for the xharbour.com flavour.

Hope it serves for your purpose.
Regards
--
Claudio Voskian
Buenos Aires - Argentina

---
// Server side
// This example is the server side of a TCP/IP communication between
// processes. The server socket is created with INetServer() and then
// configured with a timeout value. As a result, INetAccept() returns
// every half second when there is no connection request. This allows
// for querying the keyboard two times a second and check if the user
// pressed a key to terminate the server process.
//
// Note: the example must be built as multi-threading application
// e.g. Xbuild -mt TestServer

PROCEDURE Main
LOCAL pServer, pClient

CLS

INetInit()

// listen on port 1800
pServer := INetServer( 1800 )

// stop listening after .5 seconds
INetSetTimeout( pServer, 500 )

? "Server up and running", pServer
? "Press any key to quit"

DO WHILE Inkey(.1) == 0
// wait for incoming connection requests
pClient := INetAccept( pServer )

IF INetErrorCode( pServer ) == 0
// process client request in separate thread
StartThread( @ServeClient(), pClient )
ELSE
// display some kind of "I am still alive" message
?? "."
ENDIF
ENDDO

// make sure second thread has ended
WaitForThreads()

// close socket and cleanup memory
INetClose( pServer )
INetCleanup()
RETURN

PROCEDURE ServeClient( pSocket )
LOCAL cBuffer, nBytes, cData := ""

// display IP address of client
? "Serving:", INetAddress( pSocket )

// wait until data containing CRLF has arrived
// (this is blocking the thread)
cData := INetRecvLine( pSocket, @nBytes )

? "Bytes received:", nBytes
? "Data received:", cData

cData := "Server reports: " + ;
LTrim(Str( nBytes )) + ;
" bytes " + INetCRLF()

// report to client process
INetSend( pSocket, cData )
RETURN

// Client side
// This example is the client side of a TCP/IP communication between
// processes. The server IP address defaults to "127.0.0.1", which is
// the IP address of the local station. The user can enter data in a
// single GET. This data is transferred to the server process, and the
// response of the server process is displayed in the client process.
//
// Note: the example can be built as a single threaded application
// e.g. Xbuild TestClient

#include "Inkey.ch"

PROCEDURE Main( cServerIPAddress )
LOCAL pSocket, cData, nBytes

IF Empty( cServerIPAddress )
// IP address of the local station
cServerIPAddress := "127.0.0.1"
ENDIF

INetInit()

DO WHILE Lastkey() <> K_ESC
CLS

// let the user enter some data
cData := Space(80)
@ 2,2 SAY "Enter a string:" GET cData PICTURE "@S30"
READ

IF Lastkey() == K_ESC
EXIT
ENDIF

cData := Trim( cData )
nBytes := Len ( cData )

// connect to server on port 1800
pSocket := INetConnect( cServerIPAddress, 1800 )

IF INetErrorCode( pSocket ) <> 0
? "Socket error:", INetErrorDesc( pSocket )
INetCleanUp()
QUIT
ENDIF

// Send data and append "new line" characters
// This is what the "example server" expects
INetSend( pSocket, cData + INetCRLF() )

CLS
? "sent:", LTrim(Str(nBytes)), "bytes"

// Receive the server's response
cData := ""

DO WHILE nBytes > 0
cBuffer := Space( 100 )
nBytes := INetRecv( pSocket, @cBuffer )
cData += Left( cBuffer, nBytes )
ENDDO

// disconnect from server
INetClose( pSocket )

? "received:", cData
WAIT
ENDDO

INetCleanUp()
RETURN
---

Hello
> Hello developers,
> > I know you don't have much free time.
> > So I wanted to find an anti-software piracy solution. I've been thinking about creating a server/client with a socket, and hosting it in the cloud, to run in the cloud, and the client checking if it is enabled to continue running my system.
> >
> > I really don't know how to do this above.
> >
> > So thanks a lot for any help,
> >
> > Reynaldo Henrique
> Hi Reynaldo
>
> I have developed an applet for taking snapshots (screenshots) from users periodically, and the pictures are sent to a "server" hosted wherever you wish, as it depends on internet service (it could be a server in the LAN or in any other external host).
> It is based on the code below, obviously modified in many different ways.
>
> This code was published in the docs for the xharbour.com flavour.
>

Helo Claudio,

Thank you very much.

I tested the codes, and it worded very well. I doesn't compiled with xharbour but only with xharbour builder.

Reynaldo Henrique